مائیکروسوفٹ ایکسل میں کسی بھی رقم کی ویلیو کو خود کار طور پر الفاظ (Amount in words)میں تبدیل کرنا

 

دوستو! آج ہم آپ کو بتائیں گے کہ کس طرح ایکسل شیٹ میں رقم کے مجموعے کو خود کا طور پر الفاظ میں تبدیل کرتے ہیں جسے اصطلاحی طور پر (Amount in words) کہتے ہیں۔

اس مقصد کے لئے ہم ایکسل میں میکروز کا استعمال کریں گے ۔

سب سے پہلے جس ورک شیٹ میں اماؤنٹ اِن ورڈز کو خودکار کرنا ہے اسے اوپن کرلیں۔

اب آپ ویژول بیسک ایڈیٹر کو اوپن کرلیں۔

اب آپ کے پاس بائیں پینل میں ایکسل فائل کی تمام شیٹس کی لسٹ دکھائی دے گی اور سب سے آخر میں مکمل ورک بُک کا آپشن دکھائی دے گا

اگر آپ نے یہ سارا عمل کسی ایک شیٹ کے لئے کرنا ہے تو اُس شیٹ پر کلک کریں ورنہ مکمل ورک شیٹ پر کلک کردیں۔

ماڈیول پر کلک کرنے پر  جو ونڈو اوپن ہوگی وہاں آپ نے نیچے دیا گیا تمام کوڈ کاپی پیسٹ کرنا ہے۔

Option Explicit
'Main Function
Function SpellNumber(ByVal MyNumber)
    Dim Rupees, Paisas, Temp
    Dim DecimalPlace, Count
    ReDim Place(9) As String
    Place(2) = " Thousand "
    Place(3) = " Million "
    Place(4) = " Billion "
    Place(5) = " Trillion "
    ' String representation of amount.
    MyNumber = Trim(Str(MyNumber))
    ' Position of decimal place 0 if none.
    DecimalPlace = InStr(MyNumber, ".")
    ' Convert paisas and set MyNumber to rupee amount.
    If DecimalPlace > 0 Then
        Paisas = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
                  "00", 2))
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case Rupees
        Case ""
            Rupees = "No Rupees"
        Case "One"
            Rupees = "One Rupee"
         Case Else
            Rupees = Rupees & " Rupees"
    End Select
    Select Case Paisas
        Case ""
            Paisas = " and No Paisas"
        Case "One"
            Paisas = " and One Paisa"
              Case Else
            Paisas = " and " & Paisas & " Paisas"
    End Select
    SpellNumber = Rupees & Paisas
End Function
      
' Converts a number from 100-999 into text
Function GetHundreds(ByVal MyNumber)
    Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
    MyNumber = Right("000" & MyNumber, 3)
    ' Convert the hundreds place.
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    End If
    ' Convert the tens and ones place.
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
    GetHundreds = Result
End Function
      
' Converts a number from 10 to 99 into text.
Function GetTens(TensText)
    Dim Result As String
    Result = ""           ' Null out the temporary function value.
    If Val(Left(TensText, 1)) = 1 Then   ' If value between 10-19...
        Select Case Val(TensText)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
            Case Else
        End Select
    Else                                 ' If value between 20-99...
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
            Case Else
        End Select
        Result = Result & GetDigit _
            (Right(TensText, 1))  ' Retrieve ones place.
    End If
    GetTens = Result
End Function
     
' Converts a number from 1 to 9 into text.
Function GetDigit(Digit)
    Select Case Val(Digit)
        Case 1: GetDigit = "One"
        Case 2: GetDigit = "Two"
        Case 3: GetDigit = "Three"
        Case 4: GetDigit = "Four"
        Case 5: GetDigit = "Five"
        Case 6: GetDigit = "Six"
        Case 7: GetDigit = "Seven"
        Case 8: GetDigit = "Eight"
        Case 9: GetDigit = "Nine"
        Case Else: GetDigit = ""
    End Select
End Function

اب آپ نے  تمام ورکنگ کو سیو کرتے ہوئے ویژول بیسک ایڈیٹر کو بند کردینا ہے جیسا کہ نیچے امیج میں دکھایا گیا ہے۔

اب آپ نے کرسر اُس سیل میں لے جانی ہے جہاں آپ نے اماؤنٹ اِن ورڈز پرنٹ کروانا ہے

یہاں آپ نے ایف 2 پریس کرنا ہے اور مندرجہ ذیل کوڈ کاپی پیسٹ کرنا ہے۔

1	=@SpellNumber(E16)

اس کوڈ میں بریکٹ میں دکھائی دے رہے ای 16 کے بجائے آپ نے وہ سیل کوٹ کرنا ہے جہاں رقم ہندسوں میں موجود ہو مثال کے طور پر بی 5 یا ڈی 15 یا کچھ بھی، جیسا کہ نیچے امیج میں شو ہو رہا ہے۔

اب آپ اینٹر پریس کریں گے تو آپ دیکھیں گے کہ ای 16 میں موجود ہندسے الفاظ کی صورت میں ٹارگٹ سیل میں ڈسپلے ہورہے ہیں۔

آپ ایک ہی شیٹ  میں کئی بار اماؤنٹ اِن ورڈز کی کمانڈ استعماال کرسکتے ہیں  مگر ہر بار سورس سیل کا ریفرنس احتیاط سے لکھنا ہوگا

جی دوستو! امید ہے آپ کو سارا طریقہ کار سمجھ آگیا ہوگا، کسی بھی قسم کی دقت اور پریشانی کی صورت میں کمنٹ کریں اور اپنی پریشانی کا حل حاصل کریں۔

آپ سب کا بے حد شکریہ